레이블이 매스매티카인 게시물을 표시합니다. 모든 게시물 표시
레이블이 매스매티카인 게시물을 표시합니다. 모든 게시물 표시

2017년 12월 15일 금요일

외부에서 생성한 그물망(mesh) 정보를 매스매티카에서 불러올 수 없겠느냐는 의뢰를 받았다. 의뢰자가 보낸 그물망 파일을 살펴보니, 다음의 세 단락으로 구성되어 있다.

% Coordinates
8.9230056E-8             -1.1747189E-8            
8.737304E-8              -1.2470854E-8
…

% Elements (triangular)
2         3         5         
4         5         8  
…

% Data
0.0                      
0.0
…

각 노드의 좌표, 그 좌표로 구성된 삼각형 요소, 그리고 각 노드의 계산 값으로 구성된 세 단락으로 구성되어 있으며, 각 단락은 %로 시작하는 줄로 구분된 걸 알 수 있다. 이걸 어떻게 불러들여야 하나? 먼저, STL 형식으로 불러들이려고 했지만, 실패. STL 형식은 3차원 데이터만 다루도록 되어있나 본데, 이건 2차원 그물망이라서 그런가보다.

구글 검색에도 딱히 걸리는 게 없다. 조금 당황했지만, 다행히 Wolfram Documentation Center의 문서 중에서 쓸만한 예제를 찾았다. 먼저 검색해본 건, 실제 그물망 정보를 담고 있는 ElementMesh 함수이다. 이 함수는 Property가 많아서 직접 만들어주는 건 어렵겠다 싶어서 살펴보던 중에 찾은 건, ElementMesh를 생성해주는 ToElementMesh 함수이다. 드디어 이 함수의 예제 중에서 적합한 예제를 찾았다.



각 노드의 좌표와 삼각형 요소 정보만으로 ElementMesh를 만들어주니까, 필요한 정보는 다 있다. 그물망에 관한 함수를 다루려면 FEM 꾸러미를 불러와야 한다.


그럼, 이제 그물망 파일을 어떻게 불러들일 것인가? 다른 언어처럼 한 줄씩 읽어들여서 구문분석(parsing)을 돌리는 건 좀 Wolfram 언어답지 않고 말이지. 먼저 그물망 정보를 Table 형식으로 불러와 보자.


2차원 리스트로 잘 불러왔군. 다행히도 각 단락의 열 길이가 다르다는 걸 이용하면 쉽게 각 단락을 구분할 수 있다. 2열로 구성된 부분만 노드의 좌표를 나타내고 있으므로 {_,_} 패턴을 이용해서 해당 부분만 골라낼 수 있다.


여기서 단락 구분 겸 메타데이터로 쓰이는 “%”로 시작하는 줄을 간단히 빼버리는 방법도 있겠지만, 패턴 검사를 이용하면 조금 더 우아하게 처리할 수 있다. 열의 첫 번째 원소가 “%”인 것들은 빼고 골라내자.



삼각형 요소도 똑같은 방식으로 골라낼 수 있다. 삼각형 단락은 3열로 이루어져 있으므로, {_,_,_}패턴을 이용해서 골라낼 수 있다. 결과는 ToMeshElement의 “MeshElement” 옵션의 형식을 참고해서 결과 형식을 맞춰주면 된다.


모든 준비는 끝났고, 이재 ToElementMesh 함수를 이용해서 ElementMesh를 생성하면 된다.



ElementMesh는 제대로 생성이 되었다. 그물망의 품질이 떨어진다는 경고의 원인을 잘 모르겠지만, 아마도 그물망 좌표의 유효자리수가 문제가 아닐까 한다. 그럼, 매스매티카가 불러들인 그물망을 확인해보자.


내가 할 일은 여기까지인 것 같다. 결과를 송부하고 잠이나 자야겠다.


2013년 9월 5일 목요일

매스매티카 9.0.1에서 NVIDIA 그래픽카드 설정하기

CUDA 지원


우분투 13.04에 NVIDIA의 그래픽칩을 사용하는 그래픽카드가 설치되어 있고, NVIDIA의 독점 그래픽 드라이버가 설치 되어 있다고 가정한다. 매스매티카의 도움말을 따르면 이 단계에서 다음의 테스트를 통과해야 한다.
In[1]:= << CUDALink`
In[2]:= CUDAQ[]
Out[2]= False
하지만 실패! 인터넷을 뒤져보니, 이건 매스매티카가 CUDA 라이브러리를 찾지 못해서 발생하는 문제로 환경 변수 설정이 필요한 걸 알 수 있다. 내 경우엔 NVIDIA 그래픽 드라이버 버전이 319.37이므로 이에 해당하는 라이브러리를 찾아 환경변수에 등록해준다.
--- /etc/profile.d/Mathematica.sh.orig 2013-10-09 00:19:53.671638435 +0900
+++ /etc/profile.d/Mathematica.sh 2013-10-09 00:20:15.543638995 +0900
@@ -1,2 +1,4 @@
 #!/bin/sh
 export MATHEMATICA_HOME=/opt/Wolfram/Mathematica/9.0
+export NVIDIA_DRIVER_LIBRARY_PATH=/usr/lib/nvidia-current/libnvidia-tls.so.319.37
+export CUDA_LIBRARY_PATH=/usr/lib/nvidia-current/libcuda.so
이제 다시 로그인 한 후에 매스매티카를 실행해보면 위의 테스트를 깔끔히 통과한다.

OpenCL 지원


자신의 NVIDIA 칩이 OpenCL을 지원한다면, 매스매티카의 OpenCL 인터페이스도 사용할 수 있다. 지원 여부는 위키피디아에서 확인할 수 있다.
In[1]:= << OpenCLLink`
In[2]:= OpenCLQ[]
Out[2]= False
역시 실패! 여기에 따르면, 매스매티카가 엉뚱한 위치에서 OpenCL 라이브러리 찾기 때문이다. 더욱이 이 위치는 고정되어 바꿀 수 없다. 따라서 매스매티카가 찾는 위치에 맞추어서 링크를 만들어줘야 한다.
$ sudo mkdir -p /usr/lib64
$ sudo ln -s /usr/lib/nvidia-current/libOpenCL.so /usr/lib64/
이제 매스매티카 커널을 재시작하고 위 테스트를 실행해보면, 문제없이 통과!

CUDA 개발환경(Toolkit) 지원 컴파일러


매스매티카에서 제공하는 내장 CUDA 함수는 잘 동작한다. 하지만 외부 CUDA 함수를 매스매티카로 불러오면 gcc 4.7 이상은 지원하지 않는다는 에러가 발생한다.
In[2]:= code = "__global__ void addTwo(mint * in, mint * out, mint length) {
int index = threadIdx.x + blockIdx.x*blockDim.x;
if (index < length)          out[index] = in[index] + 2;  }";


In[3]:= cudaFun = CUDAFunctionLoad[code, "addTwo", {{_Integer, _, "Input"}, {_Integer, _,     "Output"}, _Integer}, 256]
During evaluation of In[3]:= CUDAFunctionLoad::cmperr: -- Message text not found -- (/home/kwchun/.Mathematica/Paclets/Repository/CUDAResources-Lin64-9.0.0.0/CUDAToolkit/bin/../include/host_config.h:82:2: error: #error -- unsupported GNU version! gcc 4.7 and up are not supported!) >>


Out[3]= CUDAFunctionLoad["__global__ void addTwo(mint * in, mint * out, mint length) {int index = threadIdx.x + blockIdx.x*blockDim.x;
if (index < length) out[index] = in[index] + 2;}", "addTwo", {{_Integer, _, "Input"}, {_Integer, _,    "Output"}, _Integer}, 256]
에러에 나와 있듯이 2013년 9월 5일 현재 매스매티카의 CUDA 개발환경(Toolkit) 버전은 9.0.0.0이고, 이 버전은 gcc 4.7 이상을 지원하지 않는다. 이 문제는 "XCompilerInstallation" 옵션으로 CUDA 개발환경이 지원하는 C 컴파일러의 경로를 지정하면 해결된다.
In[4]:= cudaFun = CUDAFunctionLoad[code, "addTwo", {{_Integer, _, "Input"}, {_Integer, _, "Output"}, _Integer}, 256, "XCompilerInstallation" -> "/usr/bin/gcc-4.6"]
Out[4]= CUDAFunction["<>", "addTwo", {{_Integer, _,    "Input"}, {_Integer, _, "Output"}, "Integer64"}]

OpenCL에서 배정도 부동소수점 사용


(아마도) 64비트 환경에서 OpenCL 외장 함수 내에 배정도 부동소수점을 사용하면 아래와 같이 함수를 불러드릴 수 없다.

code = "
  __kernel void addTwo(__global Real_t *in, __global Real_t *out, mint length) {
        int index =  get_global_id(0);
        if (index < length)
            out[index] = in[index] + 2;
    }";
openclFun = 
 OpenCLFunctionLoad[code, 
  "addTwo", {{_Real, _, "Input"}, {_Real, _, "Output"}, _Real}, 256, 
  "ShellOutputFunction" -> Print ]

OpenCLFunctionLoad::cmpf: The kernel compilation failed. Consider setting the option "ShellOutputFunction"->Print to display the compiler error message. >>

:2:31: error: must specify '#pragma OPENCL EXTENSION cl_khr_fp64: enable' before using 'double'
__kernel void addTwo(__global Real_t *in, __global Real_t *out, mint length) {
                              ^
In file included from <built-in>:17306:
<command line>:4:16: note: instantiated from:
#define Real_t double
               ^

이건 에러 메시지에도 나와 있듯이, OpenCL 관련 매크로를 코드의 앞부분에 넣어주면 해결된다.
code = "
  #ifdef USING_DOUBLE_PRECISIONQ
  #ifdef OPENCLLINK_USING_NVIDIA
  #pragma OPENCL EXTENSION cl_khr_fp64: enable
  #else /* OPENCLLINK_USING_NVIDIA */
  #pragma OPENCL EXTENSION cl_amd_fp64: enable
  #endif /* OPENCLLINK_USING_NVIDIA */
  #endif /* USING_DOUBLE_PRECISIONQ */

  __kernel void addTwo(__global Real_t *in, __global Real_t *out, mint length) {
    int index =  get_global_id(0);
    if (index < length)
      out[index] = in[index] + 2;
}";

2011년 10월 15일 토요일

두 개의 대전된 진자

울프램 사에선 Wolfram Demonstrations Project를 운영하고 있다. 이 홈페이지에선 매스매티카로 만든 다양한 프로그램을 만날 수 있는데, 이름에서 볼 수 있듯이 여기 있는 프로그램의 목적은 보여주기 위한 것이다. 예를 들어, 과학 책에 등장하던 고정된 그림과 그래프를 다양하게 변화시켜 가며 체험해 볼 수 있다. 여기에 등록할 프로그램은 유료 프로그램인 매스매티카로 만들어야 하지만, 실행해 보는 데에는 무료 프로그램인 Wolfram CDF Player만 있으면 되므로 누구나 프로그램을 실행해 볼 수 있다.

2차원 진자의 운동
최근에 이 프로젝트에 2차원 진자를 전산 모의 실험해 볼 수 있는 프로그램을 하나 올렸다. 진자(pendulum, 흔들이)란 어떤 물체를 줄에 매달아 흔들리게 둔 장치를 말하는데, 쉽게 괘종시계의 추를 생각하면 된다. 이 간단한 동역학 모델은 생각과 달리 정확한 해를 구할 수 없는데, 꽤 정확한 근사는 할 할 수 있다. 물리학도가 처음으로 만나는 진동계로써 교육적으로 중요한 모델일 뿐만 아니라, 물리학자로 살아가는 동안 계속 만나게 되는 진동계로써 과학에 이바지하는 바도 크다.

내가 만든 프로그램에 나오는 진자는 평면상에서 움직이는 2차원 진자이다. 보통 진자의 움직임을 계산할 때 진자의 움직임 폭이 줄의 길이에 비해 짧다는 가정을 하는데, 이렇게 하면 원래 비선형 움직임을 보이는 진자를 선형계로 근사할 수 있다. 하지만, 내 프로그램은 이 근사를 사용하지 않고 더 정확한 계산을 시도한다. 하지만 이 프로그램도 현실과 다른 사항을 몇 개 가정한다. 추를 매단 줄에 관한 건데, 이 줄의 형태는 변하지 않으며 무게가 0이라고 가정한다. 이 밖에 다른 근사도 사용하지만, 이건 아래에서 다루기로 하자.

Two Charged Conducting Pendulums의 실행 화면
프로그램에는 진자가 한 개가 아닌 두 개가 나온다. 프로그램을 실행해 보면 알겠지만, 이 두 개의 진자는 서로 연결되어 있다. 눈에 보이는 장치에 의해 연결된 건 아니고, 전기력에 의해 연결되어 있다. 바로 진자의 추에 대전 된 전하량을 설정할 수 있게 되어 있기 때문이다. 그리고 두 개의 추는 완전 도체로 만들어진 구라고 가정한다. 물체 근처에 전하를 가져가면 전하와 물체 사이엔 서로 끌어당기는 힘이 작용하게 되는데, 이 물체가 완전 도체로 이루어진 구라면, 이 힘을 쉽게 계산할 수 있다. 다만, 여기에서 문제는 어느 한 쪽의 전하가 공기 중에 있지 않고 양쪽 모두 도체 구에 분포한다는 점이다. 이렇게 되면, 무한수열을 계산해야 하고, 정확한 계산을 위해선 시간이 좀 걸린다. 이 프로그램은 실시간으로 미분방정식을 풀어서 움직임을 보여줘야 하는데, 이래서는 사용자가 좀 지루할 것 같다. 그래서 다시 근사를 한다. 이 수열의 각 항은 크기가 급격히 감소하므로, 수열 중 첫 번째 항만을 이용해서 계산한다. 사실 이렇게 해도 꽤 그럴싸한 값을 얻을 수 있기 때문이다.

이 프로그램에선 거의 모든 값을 사용자가 변경해 볼 수 있다. 또한, 전산 모의 실험에선 일반적으로 이러한 매개 변수의 단위를 없애지만, 이 프로그램의 조정 패널에선 실제 단위를 사용하게 하였다. 덕분에 왼편의 조정 패널에 나타나는 숫자가 조금 지저분해 보이긴 하지만, 사용자가 실제 수치에 조금 더 사실적은 감을 얻을 수 있을 거라 여긴다.

2011년 4월 1일 금요일

미분방정식의 분석

y'[t] == y[t] (4 - y[t])란 미분방정식을 분석해보자. 초기 조건을 y[0] == 0이나 y[0] == 4로 주면 y'[t]==0이니, t에 무관하게 각각 0과 4에 머무는 것을 예측할 수 있다. 더 구체적인 분석에 앞서, 백문이 불여일견이라 했으니 방향장(direction field)을 한 번 그려보자.
StreamPlot[{1, y (4 - y)}, {t, 0, 5}, {y, -5, 5},
 FrameLabel -> {t, y}]
y'=y(4-y)의 방향장 그래프
y[0]을 초기 조건으로 잡는다면, y[0]이 0보다 크면, 4로 수렴하고 y[0]이 0보다 작으면 음의 무한대로 발산하는 것처럼 보인다. 과연 그럴까? 초기 조건을 y[0] == -2로 해서 미분방정식을 실제로 풀어보자.
DSolve[{y'[t] == y[t] (4 - y[t]), y[0] == 4}, y[t], t]
Equal @@ %[[1, 1]]
Map[Limit[#, t -> Infinity] &, %]

이게 어찌 된 일일까? 초기 조건을 0보다 작게 두었는데, 발산하지 않고 4로 수렴한다는 결과가 나왔다. 미분방정식의 해를 그래프로 그려보면 이유를 알 수 있다. 
Plot[(4 Exp[4 t]))/(-3 + Exp[4 t]), {t, 0, 3}, PlotRange -> {-5, 9}, 
 AxesLabel -> {t, y}]
y'=y(4-y)의 해를 그린 그래프

y[t]는 -2에서 출발해서 Log[3]/4에서 음의 무한대로 발산한다. Log[3]/4의 오른쪽은 양의 무한대에서부터 시작해서 4로 수렴하게 된다. 즉 Log[3]/4라는 특이점(singularity)이 존재한다.

2011년 2월 10일 목요일

이맥스의 정규 표현식 치환 기능

드디어 매스매티카 8을 쓸 수 있게 되었다. 이전 버전에서 작업하던 파일을 열어 실행하니 왠 걸. 떡하니 에러가 뜬다.

매스매티카 8.0의 변경사항으로 인해 발생하는 오류


난 매스매티카를 주로 이론적 분석, 즉 수식전개 등에 사용하는데, 종종 중간 결과를 수식번호 형식으로 저장해 놓는다. 해당 장(chapter)과 각 장에서의 수식번호를 나타내는 eq15\[Dash]8과 같은 형식의 변수명을 사용하는데, 여기서 문제가 발생했다. 이전 버전까지는 eq15-8을 단일 변수명으로 봤는데, 8.0에서는 이를 eq15, \[Dash], 8의 곱으로 인식한다.

어차피 각 장은 별도의 파일에 저장하고 있으므로, 변수명에서 장 번호를 없애기로 했다. 그러면 변수명을 eq8과 같이 \[Dash] 없이 쓸 수 있으므로 문제를 해결할 수 있다. 파일 마다 많게는 100여개에 이르는 수식번호를 어떻게 일일이 다 바꿀까? 매스매티카에서 하기는 어려울 것 같다. 간단한 방법을 생각해보면, sed를 이용할 수도 있고 이맥스의 치환 기능을 이용할 수도 있겠다. 일단 변환할 문자열의 형태를 알아야 하니, 이 파일을 이맥스에서 열어보자.

이 부분의 해석 방식이 바뀌었다.

해당 부분의 입력이 위와 같이 저장된 것을 알 수 있다. 이제 이러한 패턴을 찾아서 바꾸면 된다. replace-regexp(C-M-%) 명령을 이용하면, 정규 표현식으로 위와 같은 패턴의 문자열을 모두 찾아서 바꿀 수 있다. 위 그림에서 강조한 부분을 나타내는 정규 표현식은 아래와 같다.
RowBox\[{"eq15", "\\\[Dash\]", "[0-9][0-9]*"}\]
하지만, 문제가 하나 있다. 패턴은 이게 맞는데 매번 치환마다 수식번호를 그것에 맞게 바꿔줘야 한다. 그렇지 않으면 모든 수식번호가 하나로 바뀌게 된다. 이건 패턴의 변수 기능을 이용하면 해결할 수 있다. 먼저, 수식번호에 해당하는 부분을 괄호로 둘러싼다. Query replace regexp:에 입력할 정규 표현식은 아래와 같다.
RowBox\[{"eq15", "\\\[Dash\]", "\([0-9][0-9]*\)"}\]
괄호로 둘러싼 부분은 치환된 문자열에서 \1로 불러올 수 있다. 괄호가 두 개 이상이면 \2, \3 등으로 불러올 수 있다. 즉, with:에 입력할 패턴은 아래와 같다.
"eq\1"
일치하는 문자열을 한번에 모두 치환하려면 Query replacing이 진행 중일 때, !를 입력하면 된다.

replace-regexp를이용하여 치환하는 모습

문자열 치환을 마치고, 파일을 저장한다. 이제 수정한 파일을 매스매티카에서 열어보자.

노트북 파일을 매스매티카 외부에서 수정하면 저장된 임시 계산 결과를 이용할 수 없다.

경고창이 하나 뜨는며 살짝 겁을 준다. 잘 읽어보면, 수정된 파일이므로 임시 저장 결과를 이용할 수 없다는 안내이다. 친절하게도 내용에는 문제가 없을 거라며 안심 시켜준다. OK를 클릭해서 넘어간다. 수식을 다시 실행해보면, 문제가 해결된 것을 볼 수 있다.

이맥스와 정규 표현식을 이용하면 문제가 되는 부분을 한 번에 모두 치환할 수 있다.

2010년 10월 27일 수요일

오일러의 수, 전기장, 에너지

매스매티카 사용자에게 오일러의 수, 전기장, 에너지를 생각하면 떠오르는 건 뭘까? 방정식에서 모두 E로 표기된다는 점이다. 그래서 문제가 발생한다. 실수로 아래와 같이 입력하면,
E == m c^2
결과는




이 된다. 이 방정식은 좌변은 오일러의 수로 상수를 나타내므로 틀린 식이다. 매스매티카에서 대문자 E는 오일러의 수를 가리킨다. 즉, 매스매티카에서 E 또는 Esc+ee+Esc, 혹은 \[ExponentialE]를 입력하면 이건 오일러의 수를 나타낸다. 그럼, 전기장이나 에너지를 뜻하는 변수로 E를 쓸 수는 없을까? 유감스럽게도 그렇다. 다른 문자를 사용해야 한다. 하지만, 대안이 있다. 보기에 E와 비슷한 문자를 사용할 수는 있다. \[CapitalEpsilon] 즉, 그리스 문자 ε의 대문자가 E와 비슷하게 생겼는데, 이걸 사용하면 된다.
\[CapitalEpsilon] == m c^2
라고 입력하면 쓸만한 결과를 얻을 수 있다.




다행히도 단축키도 있어서 매번 \[CapitalEpsilon]을 입력할 필요도 없다. 단축키는 Esc+E+Esc이다.

x에 대하여 정리하면...

대중에게 알려진 가장 유명한 방정식은 아인슈타인의 에너지와 질량의 동등성을 나타내는
e == m c^2
일 것 같다. 여기서 m은 물체의 질량, c는 진공에서 빛의 속도, 그리고 e는 이 질량에 저장된 에너지를 뜻한다. 이 방정식을 m에 관해 정리하려면, 즉 m만 좌변에 남기고 모두 우변으로 옮기려면 어떻게 해야 할까? 방정식을 m에 관해 풀면 된다.
e == m c^2
% // Solve[#, m] &
결과는 방정식이 아닌 Rule로 주어진다. 이걸 방정식으로 바꾸려면, 아래와 같이 리스트(List)를 벗겨 내고, 헤더를 Equal로 바꿔주면 된다.
e == m c^2
% // Solve[#, m][[1, 1]] & // Equal @@ # &
그럼, c^2에 관해 정리하려면 어떻게 해야 할까? 위와 같은 방법으로 하면 c^2가 적절한 변수가 아니라는 오류 메시지를 보게 될 뿐이다. 이럴 땐, c^2를 잠시 HoldForm으로 잡아두면 문제를 해결할 수 있다.
e == m c^2
% /. c^2 -> HoldForm[c^2] // Solve[#, HoldForm[c^2]][[1, 1]] & // 
  ReleaseHold // Equal @@ # &
Solve로 항을 정리한 후에 ReleaseHold를 사용하면 간단하게 HoldForm을 제거할 수 있다.

2010년 9월 26일 일요일

주기율표에 나오는 원소기호로 만들 수 있는 가장 긴 단어는?

KAIST의 정재승 교수가 트위터에 던진 질문인데, 인터넷에서 몇몇 분이 이 문제를 풀었다. 그 중, 조승연 씨가 파이썬으로 작성한 코드는 아래와 같다.
#!/usr/bin/env python
# -*- coding: utf-8 -*-

import re

f = open("/usr/share/dict/words", 'r')
maxlen = 0
maxword = ""
pattern = r"^(Ac|Al|Am|Sb|Ar|As|At|Ba|Bk|Be|Bi|Bh|B|Br|Cd\
|Ca|Cf|C|Ce|Cs|Cl|Cr|Co|Cu|Cm|Ds|Db|Dy|Es|Er|Eu|Fm|F|Fr\
|Gd|Ga|Ge|Au|Hf|Hs|He|Ho|H|In|I|Ir|Fe|Kr|La|Lr|Pb|Li|Lu|Mg\
|Mn|Mt|Md|Hg|Mo|Nd|Ne|Np|Ni|Nb|N|No|Os|O|Pd|P|Pt|Pu|Po\
|K|Pr|Pm|Pa|Ra|Rn|Re|Rh|Rg|Rb|Ru|Rf|Sm|Sc|Sg|Se|Si|Ag\
|Na|Sr|S|Ta|Tc|Te|Tb|Tl|Th|Tm|Sn|Ti|W|Uuh|Uuo|Uup|Uuq\
|Uus|Uut|U|V|Xe|Yb|Y|Zn|Zr|Cn)+$"

for line in f:
   ll = line.strip()
   if re.match(pattern, ll, flags=re.IGNORECASE) and \
len(ll) > maxlen:
      maxlen = len(ll)
      maxword = ll

print maxlen, maxword
이 페이지에 나온 답은 22글자의 nonrepresentationalism이지만, 내가 가진 사전 파일에는 이 단어가 없다. 대신 19글자의 nonrepresentational이 걸린다. 이걸 매스매티카로 해보면?
FindMaxElementWord[dictFile_] :=
 Module[{maxlen = 0, maxword = "", elements, pattern, dict, word},
  elements = Table[ElementData[n, "Abbreviation"], {n, 118}];
  pattern =
   "^(" <> Drop[Flatten[Map[{#, "|"} &, elements]], -1] <> ")+$";
  dict = OpenRead[dictFile];
  word = Read[dict, Word];
  While[word =!= EndOfFile,
   If[StringMatchQ[word, RegularExpression[pattern],
      IgnoreCase -> True] &&
     StringLength[word] > maxlen, {maxlen,
      maxword} = {StringLength[word], word}];
   word = Read[dict, Word]];
  Close[dict];
  Return[{maxlen, maxword}]]
알고리듬은 위의 파이썬 코드와 같다. 다만, 원소기호를 자동으로 생성하도록 바꾸었다. FindMaxElementWord["/usr/share/dict/words"]를 실행해보면, 역시 19글자의 nonrepresentational이 걸린다.

2010년 9월 7일 화요일

상수 모으기

매스매티카를 쓰다 보면, 간단한 수식인데 깔끔하게 정리하기 어려울 때가 있다. 예를 들어, Collect[2/x - 2/y, 2]의 결과가


이렇게 나오면 좋겠지만, 결과는 2/x - 2/y이다. 2로 묶어주려면, 어떻게 해야 할까? 이런 어려움에 봉착했을 땐 우선 풀폼을 확인한다.
FullForm[2/x - 2/y]
 

풀폼에서 알 수 있듯이, 첫 번째 항은 2가 두 번째 항은 -2가 곱해져 있어서 2로 묶지 못한다. 답답하게도 -2에서 2를 빼내지 못하는군. 그럼, -2를 -1*2로 바꿔주면 되겠다 싶지만, 여기에도 문제가 있다. 매스매티카는 -1*2를 입력하면 바로 -2로 바꿔버리므로, 바꾸지 못하게 해야 한다.
2/x - 2/y
% /. -2 -> HoldForm[-1] 2
% // Collect[#, 2] & // ReleaseHold
이제 됐을까? 결과를 보면 알겠지만, 이번에도 실패다. Collect가 문제인데, Collect는 변수만을 모을 수 있기 때문이다. 그럼, 2는 변수가 아닌데 어떻게 해야 할까? 2를 HoldForm[2]로 치환해서 변수처럼 만들어주면 된다.
2/x - 2/y
% /. -2 -> HoldForm[-1] 2 /. 2 -> HoldForm[2]
% // Collect[#, HoldForm[2]] & // ReleaseHold
이제야 원하는 결과가 나오는군. 휴~

2010년 8월 18일 수요일

일부를 제외하고 치환하려면

예를 들어 {f[x], g[x], h[x]}이 있는데, x를 y로 치환한다고 하자. 이건 쉽다.
{f[x], g[x], h[x]}
% /. x -> y
이렇게 하면, {f[y], g[y], h[y]}를 얻을 수 있다. 그러면 h[x]의 x만 치환한다면? 물론 여기선 ReplaceAll[{f[x], g[x], h[x]}, h[x] -> h[y]]로 바꾸는 게 가장 쉽지만, 일반적으로는 아래처럼 하면 된다.
{f[x], g[x], h[x]}
% // MapAt[# /. x -> y &, #, 3] &
그럼 f[x]만을 제외하고 치환하려면? ReplaceAll은 한번 치환한 건 다시 치환하지 않으므로, 다음과 같이 쉽게 해결할 수 있다.
{f[x], g[x], h[x]}
% /. {f[x] -> f[x], x -> y}

2010년 8월 10일 화요일

회절 무늬

빛의 회절에는 프레넬 회절(Fresnel diffraction, near-field diffraction)과 프라운호퍼 회절(Fraunhofer diffraction, far-field diffraction)이 있는데, 흔히 회절이라 하면 프라운호퍼 회절을 일컫는다. 프라운호퍼 회절 무늬를 계산해보면 입사하는 빛의 2차원 푸리에 변환이 되는 것을 알 수 있다. 따라서, Fast Fourier Transform(FFT)을 이용해서 회절 무늬를 쉽게 그려볼 수 있다.

구멍에 들어가는 빛의 세기가 일정하다는 가정을 사용하면, 구멍의 모양이 바로 구멍을 통과하는 빛의 모양이므로 구멍의 모양을 바로 푸리에 변환하면 된다. 김프(GIMP)를 이용해서 구멍의 모양을 미리 만들어 두었다.
김프로 만든 임의의 슬릿 모양
이 이미지 파일을 불러들여, 수치 자료로 변환한다.
img = Import["spiral_aperture.png"]
data = img // ImageData;
이 자료의 모양을 확인해보면,
Dimensions[data]
{400, 400, 3}과 같이 3차원인 것을 알 수 있다. 마지막 차원은 RGB 채널 정보인데, 빛의 세기만 고려하므로 이 채널 중 하나만 뽑아 쓰면 된다.
data = img // ImageData // #[[All, All, 1]] &;
이제 자료에 FFT를 적용하면 된다. 다만, FFT에선 파수(wave number)가 0부터 2k까지로 정의되므로, RotateLeft를 이용해서 파수의 범위가 -k에서 k까지 되도록 결과 배열을 조정해줘야 올바른 회절 무늬를 볼 수 있다. 또한, ListDensityPlot은 이미지 자료와 y축 방향이 반대이므로 결과 배열을 y축에 대해서 거꾸로 그려야 한다.
data // Fourier // Abs // 
   RotateLeft[#, Ceiling[Dimensions[#]/2]] & // Reverse // 
 ListDensityPlot
꽈리 모양의 슬릿을 통과한 빛의 회절 무늬

2010년 8월 4일 수요일

변수 대입하기

다음과 같이 eq1과 eq2가 주어졌을 때, eq1에 eq2의 a를 대입하려면 어떻게 해야 할까?
F == m a
eq1 = %;
a == D[x[t], {t, 2}]
eq2 = %;
가장 일반적인 방법은 속 편하게 Eliminate 함수를 이용해서 a를 제거하는 것이다.
Eliminate[{eq1, eq2}, a]
강력한 방법이긴 하지만, 이 예와 같이 간단한 경우엔 닭 잡는 데 소 잡는 칼을 쓰는 격이다. 필요 이상으로 시간이 오래 걸리기도 하고, 때론 방정식의 형태를 보기 어렵게 만들어 놓기도 한다. 이럴 땐, 다음처럼 바로 대입하는 편이 더 낫다.
eq1 /. Rule @@ eq2

2010년 8월 3일 화요일

두 방정식의 양변을 더하라.

다음 두 방정식의 양변을 더하면?
A == B
C == D
%% + %
결과는 (A == B) + (C == D) 이다. 당연히 우리가 원하는 결과가 아니다. 매스매티카가 이 정도도 처리 못할까?
A == B
C == D
%% + % // Thread[#, Equal] &
이렇게 Thread를 이용해서 Plus를 각 변끼리 적용해주면 된다. 두 방정식이 목록으로 주어졌다면, List를 Plus로 교체하는 것만으로도 더하는 효과를 줄 수 있다.
{A == B, C == D}
Plus @@ % // Thread[#, Equal] &
그럼, 양변을 빼려면 어떻게 해야 할까? 앞의 예를 이용해서,
A == B
C == D
%% - % // Thread[#, Equal] &
이렇게? 안타깝게도 결과는 A - (C == D) == B - (C == D) 이다. 빼기가 두 번째 방정식의 양변에 적용되지 않아서 이런 결과가 나온다. 그러므로 양변을 더하기 전에 C == D의 양변에에 각각 -1을 곱해주어야 한다.
A == B
C == D
%% + (-1 # &) /@ % // Thread[#, Equal] & 

2010년 8월 2일 월요일

변수의 값 맞바꾸기

C++과 매스매티카, 파이썬에서 변수의 값을 맞바꾸는 코드를 비교해보자. C++은 아래와 같다. 표준적인 swap 함수의 형태를 보여준다.
template <T>
void swap(T &x, T &y)
{
    T tmp(x);
    x = y;
    y = tmp;
}
매스매티카에선 좀 더 간단하다. 목록을 만들어 교환해주면 된다.
{x, y} = {y, x}
파이썬은? 변수를 나열하면 자동으로 튜플을 만들어 주므로, 코드가 더 간단해진다.
x, y = y, x

2010년 7월 29일 목요일

구 표면 위의 벡터 필드 그리기

먼저 1 C(쿨롱)과 -1 C의 전하가 각기 (0,0,-1)과 (0,0,1)의 위치에 있을 때, 이들이 생성하는 전기장을 구해보자. 이들 두 전하가 만드는 포텐셜을 구하고, 이 포텐셜의 음의 기울기를 구하면 전기장을 알 수 있다.
φ[x, y, z] == 1/(4 π Subscript[ε, 0])
(1/Norm[{x, y, z} - {0, 0, -1}] - 
  1/Norm[{x, y, z} - {0, 0, 1}])
% // Simplify[#, x_ \[Element] Reals] &
% // Map[-HoldForm@Grad[#, Cartesian[x, y, z]] &, #] & // 
  ReplaceAll[#, -HoldForm@
       Grad[φ[x, y, z], Cartesian[x, y, z]] -> 
     OverVector[Ε]] & // ReleaseHold
eq1 = %;


편의를 위해, 공통 계수를 없애면 아래와 같은 벡터 필드 방정식을 얻을 수 있다.
4 π Subscript[ε, 0] eq1[[2]]
eq2 = %;

이 수식을 VectorPlot3D 함수를 이용해서 필드를 그리면, 직육면체 영역 안에서 전기장을 나타내는 벡터들을 보여준다.
eq2
% // VectorPlot3D[#, {x, -1, 1}, {y, -1, 1}, {z, -1, 1},
   VectorScale -> {Automatic, Automatic, None},
   VectorColorFunction -> "Rainbow"] &

이제 원점에서 1의 거리에 있는 전기장만을 그리려면, 즉 반지름이 1인 원의 표면 위에 있는 벡터만을 그리려면 어떻게 해야 할까? ‘델타함수의 그래프 그리기’에서 한 것처럼 기본 Plot 계열의 함수가 처리해 주지 못할 때엔 ListPlot 계열의 함수를 이용하는 방법을 생각해본다.
Table[{r, θ, ф}, {r, 1, 1}, {θ, 0, π, π/
    10}, {ф, 0, 2 π, π/10}] // Flatten[#, 2] &;
% // Map[CoordinatesToCartesian[#, Spherical] &, #] &;
% // Map[{#, (4 π Subscript[ε, 0]
          eq1[[2]] /. {x -> #[[1]], y -> #[[2]],
         z -> #[[3]]})} &, #] &;
% // ListVectorFieldPlot3D[#, Axes -> True,
   AxesLabel -> {"x", "y", "z"}, VectorHeads -> True,
   ScaleFunction -> (0.2 &)] &
이 복잡한 명령어들이 하는 일은 다음과 같다. 우선, 첫 번째 줄에서 구 좌표계를 이용해서 구 표면 위의 일정한 좌표를 얻는다. 두 번째 줄에선 우리가 가진 식이 직교 좌표계의 식이므로 구 좌표계의 좌표를 직교 좌표계의 좌표로 바꾼다. 세 번째 줄에선 좌표를 식에 대입해서 그래프를 그릴 자료를 생성한다. 네 번째 줄에서는 ListVectorFieldPlot3D를 이용해서 전기장의 그래프를 그린다.



버전 7.0에선 ListVectorFieldPlot3D보다 ListVectorPlot3D를 사용하길 권하지만, ListVectorPlot3D에 아직 문제가 있는 듯이 보인다.

2010년 7월 23일 금요일

델타함수 그래프 그리기

코사인 함수의 푸리에 변환은 두 델타함수의 합으로 나타난다. 하지만, 그래프로 그리면 델타함수의 피크를 볼 수 없다.
FourierTransform[Cos[1.1 t], t, ω]
% // Plot[#, {ω, -3, 3}] &


코사인 함수의 푸리에 변환으로 얻은 함수에는 그래프로 그리기 어려운 두 가지 이유가 있다. 먼저, 델타함수는 인자를 0으로 만드는 지점에서 무한대로 발산하므로 그래프로 표현하기 어렵다. 관례적으로, 델타함수를 그래프로 그릴 땐 발산 점에서 델타함수의 값을 1로 대체해서 그래프를 그린다. 즉, DiracDelta를 DiscreteDelta로 치환하면 된다. 또한, 델타함수는 연속함수가 아니어서 Plot이 발산 점을 찾아내어 그려주지도 못하는데, 이 문제는 발산 점을 포함하는 목록을 만들어서 함수 자료에 발산 점이 꼭 들어가게 하여 해결한다.
FourierTransform[Cos[1.1 t], t, ω]
% /. DiracDelta[x_] :> DiscreteDelta[x]
% // Table[{ω, #}, {ω, -3, 3, 0.001}] & //
 ListPlot[#, Joined -> True] &
이번에도 그래프엔 아무것도 나타나지 않는다. 진법 변환 오차 때문에 발생하는 문제로, DiracDelta[1.1 - (1.099 + 0.011)]를 실행해보면 1이 아닌 0이 나오는 것을 알 수 있다. 컴퓨터는 1.100과 1.099+0.001을 다른 수로 본다. 십진수로 입력한 수는 일단 이진수로 바뀌는데, 십진수 실수 중에는 이진수로 변환했을 때 무한소수가 되는 수가 있다. 예를 들어, 1.100은 이진수로 표현하면 소수점 아래 두 번째부터 다섯 번째까지가 반복하는 무한소수가 된다.
BaseForm[1.100, 2]

컴퓨터는 저장공간의 제약으로 무한소수를 일정 자리에서 버림하여 저장하는데, 이때 입력받은 십진수와 저장된 이진수 사이에 차이가 발생하게 된다. Rationalize를 이용해서 모든 수를 정수로 표현하면 이러한 문제를 없앨 수 있다.
FourierTransform[Cos[1.1 t], t, ω]
% /. DiracDelta[x_] :> 
  Hold@DiscreteDelta@Rationalize@Unevaluated@x
% // Table[{x, # /. ω -> x}, {x, -3, 3, 0.001}] & //
  ReleaseHold // ListPlot[#, Joined -> True] &

2010년 7월 22일 목요일

그래프의 특정 부분을 강조하려면

그래프에서 특정 부분을 강조하려면 Prolog나 Epilog 옵션을 이용한다. 예를 들어 코사인 그래프에서 π부터 2π까지의 영역을 강조하려면 다음과 같이 Prolog 옵션을 준다.
Plot[Cos[x], {x, 0, 10}, 
 Prolog ->; {Green, Opacity[0.1], 
  Rectangle[{\[Pi], -10}, {2 \[Pi], 10}]}]

Epilog를 이용하면 그래프를 가리게 되는데, 이때엔 Opacity 명령어로 투명도를 조절하면 숨겨진 그래프를 볼 수 있다. 이 방법은 Graphics로 표현되는 모든 그래프에서 사용할 수 있다.

2010년 7월 21일 수요일

GIST의 위도와 경도

구글 지도가 제공하는 OpenAPI인 구글 Geocoding API를 이용하면, GIST의 위도와 경도를 찾을 수 있다. 웹브라우저의 주소 입력 칸에 아래 주소를 넣으면, XML 형태의 위치 정보를 받을 수 있다.
http://maps.google.com/maps/api/geocode
/xml?address=GIST,+Oryong-dong+1,+Buk-gu,+Gwangju&
sensor=false
아래 결과를 보면, geometry 태그 아래에 위도와 경도 정보가 나와 있는 것을 알 수 있다.


구글 Static Maps API를 이용해서 우리가 얻은 위도와 경도 정보가 정확한지 확인해 볼 수 있다.
http://maps.google.com/maps/api
/staticmap?center=35.2278792,126.8415491&zoom=15&
markers=35.2278792,126.8415491&size=400 x400&sensor=false

이상의 과정을 매스매티카에서도 쉽게 재현해볼 수 있다. 먼저, XML 패키지를 읽어들인다.
<< XML`
구글 지도에서 위치 정보를 XML로 받아온다. 매스매티카는 웹브라우저와 달리 언어 정보를 보내지 않으므로, 결과를 한글로 받아오려면 언어 정보를 명시해줘야 한다.
gistXML =
 XMLGet["http://maps.google.com/maps/api/geocode
/xml?address=GIST,+Oryong-dong+1,+Buk-gu,+Gwangju&
language=ko&sensor=false"]
받아온 자료에서 위도와 경도 정보를 빼낸다.
latlng = ToExpression@
  Flatten@Cases[gistXML,
    XMLElement[
      "location", _, {XMLElement["lat", _, {lat_}],
       XMLElement["lng", _, {lng_}]}] -> {lat, lng}, Infinity]
이렇게 얻은 위도와 경도 정보를 지도로 확인해 볼 수 있다.
Block[{url, loc},
 loc = ToString /@ latlng /. {x_, y_} :> x <> "," <> y;
 url = "http://maps.google.com/maps/api/staticmap?center=" <> loc <>
   "&zoom=15&markers=" <> loc <> "&size=400x400&sensor=false";
 Import[url]
 ]
참고자료
  1. The Google Geocoding API
  2. Static Maps API V2 Developer Guide

    2010년 7월 20일 화요일

    정적분 입력 서식의 단축키

    매스매티카에서 정적분(definite integral)을 입력할 때, 단번에 입력 서식을 만들 수 있는 단축키를 제공한다. Esc+dintt+Esc를 입력하면, 다음과 같은 입력 서식이 생성된다.